Patch title: Release 87 bulk changes
Abstract:
File: /pliant/language/stream/count.pli
Key:
    Removed line
    Added line
# Copyright  Hubert Tonneau  hubert.tonneau@pliant.cx
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License version 2
# as published by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# version 2 along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.

module "ring.pli"


type CountStreamDriver
  field Link:Stream s
  field Int read_counter write_counter
  field Int read_remain 
StreamDriver maybe CountStreamDriver


method drv read buf mini maxi -> red
  oarg_rw CountStreamDriver drv ; arg Address buf ; arg Int mini maxi red
  var Int remain := shunt drv:read_remain<>undefined drv:read_remain maxi
  if remain=0
    return 0
  if drv:s:stream_read_cur<>drv:s:stream_read_stop
    drv:s read_available (var Address adr) red (min maxi remain)
    memory_copy adr buf red
  else
    red := 0
  if red<(min mini remain)
    red += drv:s:stream_driver read (buf translate Byte red) (min mini remain)-red (min maxi remain)-red
  drv read_counter += red
  if drv:read_remain<>undefined
    drv read_remain -= red


method drv write buf mini maxi -> written
  oarg_rw CountStreamDriver drv ; arg Address buf ; arg Int mini maxi written
  if drv:s:stream_write_cur<>drv:s:stream_write_buf
    drv:s flush anytime
  written := drv:s:stream_driver write buf mini maxi
  drv write_counter += written


method drv flush level -> status
  oarg_rw CountStreamDriver drv ; arg Int level ; arg Status status
  drv:s flush level
  status := shunt drv:s=success success failure


method drv query command stream answer -> status
  oarg_rw CountStreamDriver drv ; arg Str command ; arg_rw Stream stream ; arg_w Str answer ; arg ExtendedStatus status 
  if command="read_counter"
    answer := string drv:read_counter-( (cast stream:stream_read_stop Int) .-. (cast stream:stream_read_cur Int) )
    status := success
  eif command="write_counter"
    answer := string drv:write_counter+( (cast stream:stream_write_cur Int) .-. (cast stream:stream_write_buf Int) )
    status := success
  else
    status := drv:s:stream_driver query command drv:s answer


method drv configure command stream -> status
  oarg_rw CountStreamDriver drv ; arg Str command ; arg_rw Stream stream ; arg ExtendedStatus status
  if (command parse word:"read_counter" (var Int counter))
    drv read_counter := counter+( (cast stream:stream_read_stop Int) .-. (cast stream:stream_read_cur Int) )
    status := success
  eif (command parse word:"write_counter" (var Int counter))
    drv write_counter := counter-( (cast stream:stream_write_cur Int) .-. (cast stream:stream_write_buf Int) )
    status := success
  else
    status := drv:s:stream_driver configure command drv:s


#----------------------------------------------------------------


type CountFileSystem
  void
FileSystem maybe CountFileSystem


method fs open name options flags stream support -> status
  oarg_rw CountFileSystem fs ; arg Str name options ; arg Int flags ; arg_rw Stream stream support ; arg ExtendedStatus status
  var Link:Stream s
  if exists:support
    s :> support
  else
    var Link:Stream s :> new Stream
    s open name options (flags .and. in+out+safe)
    if s=failure
      return failure
  var Link:CountStreamDriver drv :> new CountStreamDriver
  drv s :> s
  drv read_counter := 0
  drv write_counter := 0
  drv read_remain := options option "size" Int
  stream stream_driver :> drv
  status := success


gvar CountFileSystem count_file_system
pliant_multi_file_system mount "count:" "" count_file_system