Patch title: Release 94 bulk changes
Abstract:
File: /pliant/graphic/browser/naive/sample/db_sample.pli
Key:
    Removed line
    Added line
module "/pliant/storage/database.pli"
module "/pliant/language/unsafe.pli"
module "/pliant/admin/file.pli"
module "/pliant/graphic/browser/naive/server.pli"
module "/pliant/graphic/browser/naive/lib/all.pli"


type SampleRecord
  field Str an_str
  field Int an_int <- undefined

type SampleDatabase
  field Str a_field
  field Str a_text
  field Str a_select
  field Set:SampleRecord records
  
file_tree_create "data:/pliant/sample/"
(gvar Database:SampleDatabase sample_database) load "data:/pliant/sample/database.pdb" mount "/pliant/sample"


browser_page "/db_sample/"
  ovar Str k
  section "all" dynamic
    window left
      section "menu" dynamic
        button "records" key "alt r"
          focus_save
          section_overwrite "menu"
            input "Key: " k focus true
            eol
            button "create" key "alt c"
              sample_database:data:records create k
              section_replay "all"
              focus_set "row "+k "row "+k 0 ""
            eol
            button "delete" key "alt d"
              sample_database:data:records delete k
              section_replay "all"
            eol
            button "escape" key "escape"
              section_replay "menu"
        eol
        button "exit" key "alt x"
          url_return
    window main
      para
        center
          font size 16*25.4/72
            bold
              text "Database sample form"
      para
        node "sample field"
          input "Sample field: " sample_database:data:a_field
      para
        input "Sample multiline text field: " sample_database:data:a_text multiline
      para
        select "Sample select: " sample_database:data:a_select
          option "value 1" "v1"
          option "value 2" "v2"
          option "value 3" "v3"
      para
        table border 0.3 padding 0.5
          row
            cell text:"key"
            cell text:"string"
            cell text:"value"
          each r sample_database:data:records
            row
              cell (text keyof:r)
              cell
                node "row "+keyof:r
                  input "" r:an_str
              cell (input "" r:an_int)
  focus_set "sample field" "sample field" 0 ""