Patch title: Release 94 bulk changes
Abstract:
File: /pliant/linux/storage/cdrom.pli
Key:
    Removed line
    Added line
module "/pliant/language/context.pli"
module "/pliant/language/stream.pli"
module "/pliant/language/stream/pipe.pli"
module "/pliant/fullpliant/this_computer.pli"
module "/pliant/linux/kernel/module.pli"
module "/pliant/linux/kernel/device.pli"
module "/pliant/admin/execute.pli"
module "/pliant/admin/file.pli"
module "/pliant/language/ui/ansi_terminal.pli"

constant debug false


function path_concat p1 p2 -> p
  arg Str p1 p2 p
  if p1:len>0 and p1:(p1:len-1)="/" and p2:len>0 and p2:0="/"
    p := p1+(p2 1 p2:len)
  else
    p := p1+p2

function cdrom_tree files path -> status
  arg List:FileInfo files ; arg Str path ; arg ExtendedStatus status
  var Pointer:FileInfo file :> files first
  while exists:file
    var Str name := file:options option "cdname" Str
    if name=""
      name := file_os_name file:name
    file_tree_create (path_concat path name)
    file_link file:name (path_concat path name)
    file :> files next file

function graft_encode c -> e
  arg Str c e
  e := replace (replace c "\" "\\") "=" "\="

function mkisofs_name file -> name
  arg FileInfo file ; arg Str name
  name := file:options option "cdname" Str
  if name=""
    name := file_os_name file:name
  if (name 0 1)="/" and name:len>1
    name := name 1 name:len
  name := "/"+graft_encode:name+"="+graft_encode:(file_os_name file:name)

function cdrom_image files options image -> status
  arg List:FileInfo files ; arg Str options ; arg Str image ; arg ExtendedStatus status
  var CBool query_size := options option "query_size"
  var Str path := options option "path" Str
  var Str boot := options option "boot" Str
  if path="" and not (exists  files:first)
    return failure:"Nothing to engrave"
  if path="" and boot<>""
    return failure:"Cannot engrave a bootable CD from a files list"
  var CBool backup := options option "backup"
  var Str mk:= "mkisofs -quiet -D"
  if (options option "linktransparent")
    mk += " -f"
  if boot<>""
    mk += " -R -b "+boot
  eif backup
    mk += " -R"
  else
    mk += " -r"
  var Str title := options option "title" Str
  if title<>""
    mk += " -V "+title
  if (options option "macintosh") and (options option "osx")
    mk += " -hfs --netatalk --osx-double"
  eif (options option "macintosh")
    mk += " -hfs --netatalk"
  eif (options option "osx")
    mk += " -hfs --osx-double"
  if (options option "windows")
    mk += " -J"
   var Str file_in file_out
  if query_size
    mk += " -print-size"
  eif file_os_name:image<>""
    mk += " -o "+file_os_name:image
  var Str extra := options option "mkisofs_extra_options" Str
  if extra<>""
    mk += " "+extra
  if path<>""
    mk += " "+file_os_name:path
  else
    var Str flist := file_temporary
    mk += " -graft-points -path-list "+file_os_name:flist+" '"+(mkisofs_name files:first)+"'"
    (var Stream s) open flist out+safe
    var Pointer:FileInfo file :> files next files:first
    while exists:file
      s writeline mkisofs_name:file
      file :> files next file
    if s:close=failure
      file_delete flist
      return failure:"Failed to generate files list temporary file"
  if debug
    console mk eol
  if query_size
    var Str ofile := file_temporary
    var Str efile := file_temporary
    var Int err := execute mk output ofile error efile
    s open ofile in+safe
    var Str oanswer := s readline
    s close
    file_delete ofile
    s open efile in+safe
    var Str eanswer := s readline
    s close
    file_delete efile
    status := shunt err=0 success (failure "mkisofs returned error code "+string:err)
    if (oanswer parse (var Intn sectors)) or (eanswer parse any "=" (var Intn sectors))
      status message := string sectors*2048n
  else
    var Int err
    part mk "Building CD "+title+" ISO9660 image"
      if file_os_name:image<>""
        err := execute mk output "file:/tmp/cdrom.log" mixed
      else
        err := execute mk output image error "file:/tmp/cdrom.log" mixed
    status := shunt err=0 success failure:"Failed to build ISO9660 image"
    if file_os_name:image<>"" and status=success and (file_query image standard)=failure
      status := failure "mkisofs internal bug"
      if debug and path<>""
        file_tree_delete "file:/tmp/bug/"
        var Array:FileInfo pfiles := file_list path standard+recursive+relative
        for (var Int i) 0 pfiles:size-1
          if (pfiles:i:name search ".AppleDouble/" -1)<>(-1)
            var Intn remain := pfiles:i:size
            (var Stream src) open path+pfiles:i:name in+safe
            (var Stream dest) open "file:/tmp/bug/"+pfiles:i:name out+safe+mkdir
            var Address buf := memory_zallocate 4096 null
            while remain>0
              var Int step := shunt remain>4096 4096 (cast remain Int)
              src raw_read buf step
              dest raw_write buf step
              remain -= step
            memory_free buf
            src close
            dest close
          else
            var Intn remain := pfiles:i:size
            (var Stream dest) open "file:/tmp/bug/"+pfiles:i:name out+safe+mkdir
            var Address buf := memory_zallocate 4096 null
            while remain>0
              var Int step := shunt remain>4096 4096 (cast remain Int)
              dest raw_write buf step
              remain -= step
            memory_free buf
            dest close
    if status=success
      file_delete "file:/tmp/cdrom.log"
    eif path=""
      file_delete "file:/tmp/cdrom.list"
      file_move flist "file:/tmp/cdrom.list"
  if path=""
    file_delete flist
  if debug
    (var Stream s) open "file:/tmp/mkisofs.log" out+safe
    s writeline mk
    if path<>""
      s writeline "path is "+string:path
      var Array:FileInfo pfiles := file_list path standard+recursive
      var Intn total := 0
      for (var Int i) 0 pfiles:size-1
        # s writeline "  "+pfiles:i:name+"  "+(string pfiles:i:size)
        total += pfiles:i:size
      s writeline (string pfiles:size)+" files "+string:total+" bytes"
    else
      var Int count := 0 ; var Intn total := 0
      var Pointer:FileInfo file :> files next files:first
      while exists:file
        # s writeline "  "+file:name+"  "+(string file:size)
        count += 1 ; total += file size
        file :> files next file
      s writeline string:count+" files "+string:total+" bytes"
    if file_os_name:image<>""
      s writeline "ISO9660 file size is "+(string (file_query image standard):size)+" bytes"
    if status=failure
      s writeline "error message is "+status:message


function cdrom_record image options -> status
  arg Str image options ; arg ExtendedStatus status
  var Str engraver := "engraver"+(options option "engraver" Str)
  var Str interface := this_computer:env:"hardware":engraver:"interface"
  var Str medium := this_computer:env:"hardware":engraver:"medium"
  if medium=""
    medium := "cd"
  var Str device := this_computer:env:"hardware":engraver:"device"
  if device=""
    device := shunt interface="ide" "device:/hdc" interface="usb" or interface="scsi" "device:/scd0" ""
  var Str engraver_options := this_computer:env:"hardware":engraver:"options"
  if not (this_computer:env:"hardware":engraver:"speed" parse (var Int speed))
    speed := undefined    
  if not (this_computer:env:"hardware":engraver:"cache_mb" parse (var Int cache_mb))
    cache_mb := memory_assigned\16\2^20
    cache_mb := max (min cache_mb 16) 4
  if interface="ide"
    kernel_unload_module "ide-cd"
    kernel_unload_module "cdrom"
    kernel_load_module "scsi_mod"
    kernel_load_module "ide-scsi"
    kernel_load_module "sg"
    sleep 5
  eif interface="usb"
    kernel_load_module "usbcore"
    kernel_load_module "ehci_hcd"
    kernel_load_module "scsi_mod"
    kernel_load_module "cdrom"
    kernel_load_module "sr_mod"
    kernel_load_module "usb_storage"
    kernel_load_module "sg"
    sleep 5
  eif interface="scsi"
    kernel_unload_module "sr_mod"
    kernel_unload_module "cdrom"
    kernel_load_module "sg"
    sleep 5
  if (engraver_options option "pio")
    execute "hdparm -d0 "+file_os_name:device quiet
  eif (engraver_options option "dma")
    execute "hdparm -d1 "+file_os_name:device quiet
  if this_computer:env:"pliant":"system":"distribution"="fullpliant"
    for (var Int i) 0 15
      kernel_make_device "device:/sg"+string:i
    for (var Int i) 0 3
      kernel_make_device "device:/pg"+string:i
  var Str dev := this_computer:env:"hardware":engraver:"scsi_id"
  if dev=""
    dev := shunt interface="ide" "0,0,0" file_os_name:(replace device "device:/scd" "device:/sg")+":@"
  eif (dev parse (var Int scsi_id))
    dev := "0,"+dev+",0"
  eif (dev parse (var Int scsi_channel) "," (var Int scsi_id))
    dev := dev+",0"
  var Str rec := shunt (options option "dvdrecord") "dvdrecord" "cdrecord"
  rec += shunt (options option "dummy") " -dummy" ""
  rec += shunt (engraver_options option "dao") " -dao" ""
  rec += shunt (engraver_options option "sao") " -sao" ""
  rec += shunt (engraver_options option "packet") " -packet" ""
  rec += shunt (engraver_options option "eject") " -eject" ""
  rec += shunt (engraver_options option "burnfree") " -driveropts=burnfree" ""
  rec += shunt (engraver_options option "overburn") " -overburn" ""
  rec += " dev="+dev
  rec += shunt speed=defined " speed="+string:speed ""
  rec += shunt cache_mb=defined " fs="+string:cache_mb+"m" ""
  if file_os_name:image="" and (options option "size")
    rec += " tsize="+(string (options option "size" Intn)\2048)
  rec += " "
  var Str stdin := "-"
  if medium<>"cd" and (options option "growisofs")
    rec := "growisofs -dvd-compat"+(shunt (options option "rw") " -use-the-force-luke" "")+" -Z "+file_os_name:device+"="
    stdin := "/proc/self/fd/0"
  var Int err
  part engrave
    if (options option "rw") and not (options option "dummy") and (engraver_options option "blank" Str)<>"no"
      var Str blank := shunt (options option "dvdrecord") "dvdrecord" "cdrecord"
      blank += " dev="+dev
      blank += shunt speed=defined " speed="+string:speed ""
      blank += " blank="+(engraver_options option "blank" Str "fast")
      if debug
        console blank eol
      part blank "Blanking read/write CD"
        var Int seconds := engraver_options option "keyboard" Int
        if seconds=defined
          stream_pipe (var Str pipe_in) (var Str pipe_out)
          thread
            (var Stream kbd) open pipe_out out+safe
            sleep seconds
            kbd writeline ""
            kbd flush anytime
          err := execute blank input pipe_in output "file:/tmp/cdrom.log" mixed
        else
          err := execute blank output "file:/tmp/cdrom.log" mixed
      if err=0
        file_delete "file:/tmp/cdrom.log"
      else
        status := failure "Failed to blank RW CD"
        if file_os_name:image=""
          (var Stream pipe) open image in+safe ; pipe close
        leave engrave
    part record "Engraving ISO9660 image on CD "+(options option "title" Str)
      if file_os_name:image<>""
        if debug
          console rec+file_os_name:image eol
        err := execute rec+file_os_name:image output "file:/tmp/cdrom.log" mixed
      else
        if debug
          console rec+stdin eol
        err := execute rec+stdin input image output "file:/tmp/cdrom.log" mixed
    if err=0
      file_delete "file:/tmp/cdrom.log"
      status := success
    else
      (var Stream log) open "file:/tmp/cdrom.log" append+safe
      log writeline ""
      log writeline rec
      log close
      status := failure "Failed to engrave the CD ISO9660 image"
      if file_os_name:image<>""
        status message += " ("+(string (file_query image standard):size)+" bytes)"
  if interface="ide"
    kernel_unload_module "sg"
    kernel_unload_module "ide-scsi"
    kernel_unload_module "scsi_mod"
    kernel_load_module "cdrom"
    kernel_load_module "ide-cd"
    sleep 5
  eif interface="scsi"
    kernel_unload_module "sg"
    kernel_load_module "cdrom"
    kernel_load_module "sr_mod"
    sleep 5


function cdrom_engrave files options -> status
  arg List:FileInfo files ; arg Str options ; arg ExtendedStatus status
  var Str engraver := "engraver"+(options option "engraver" Str)
  var Str engraver_options := this_computer:env:"hardware":engraver:"options"
  var CBool indirect := (engraver_options option "indirect") or (options option "indirect")
  if (options option "macintosh") and (options option "capacity_mb") # workarount mkisofs buggy -print-size option
    indirect := true
  var Str path := options option "path" Str
  if (options option "buggy") and path="" # workaround mkisofs buggy -graft-points option
    var Str temp := file_temporary+"/"
    cdrom_tree files temp
    status := cdrom_engrave (var List:FileInfo empty_list) options+" path "+string:temp+" linktransparent"
    file_tree_delete temp
    return
  var Int capacity_mb := options option "capacity_mb" Int
  if capacity_mb=defined
    if ((cdrom_image files options+" query_size" ""):message parse (var Intn size))
      if size>=capacity_mb*2n^20
        status := failure string:size+" bytes is too much for a CD image"
  if indirect
    var Str image := file_temporary
    status := cdrom_image files options image
    if status=success
      status := cdrom_record image options
    if status=success
      var Intn imagesize := (file_query image standard):size
      status message := string:imagesize+" bytes in the CD image"
    file_delete image
  else
    var Str extra := ""
    if (engraver_options option "size") and ((cdrom_image files options+" query_size" ""):message parse (var Intn size))
      extra += " size "+string:size
    stream_pipe (var Str pipe_in) (var Str pipe_out)
    var ExtendedStatus status1 status2
    part pipe "CD engraving pipe"
      parallel threads 2
        task
          share status1 := cdrom_image files options pipe_out
        task
          share status2 := cdrom_record pipe_in options+extra
    status := shunt status1=failure status1 status2
  if debug and status=success
    file_delete "file:/tmp/mkisofs.log"


function cdrom_file path cdname -> info
  arg Str path cdname ; arg FileInfo info
  info name := path
  info options := "cdname "+string:cdname

function cdrom_file path -> info
  arg Str path ; arg FileInfo info
  info name := path
  info options := ""

function cdrom_engrave path options -> status
  arg Str path options ; arg ExtendedStatus status
  status := cdrom_engrave (var List:FileInfo empty_list) "path "+string:path+" "+options


export cdrom_engrave
export cdrom_image cdrom_record
export cdrom_file